{
 "cells": [
  {
   "cell_type": "markdown",
   "id": "9bb241ad",
   "metadata": {},
   "source": [
    "# Erste Miniprogramme\n",
    "\n",
    "\n",
    "## Was sollte man zum Programmieren können?\n",
    "\n",
    "\n",
    "- **Denken in Algorithmen:**  \n",
    "      Welche Schritte sind zur Lösung des Problems nötig? Welche Daten müssen gespeichert, welche Datenstrukturen angelegt werden? Welche Fälle können auftreten und müssen erkannt und behandelt werden?  \n",
    "- **Umsetzung des Algorithmus in ein Programm:**     \n",
    "      Welche Datenstrukturen, Konstrukte, Funktionen... stellt die Programmiersprache bereit? \n",
    "- **Formale Syntax:**   \n",
    "      Menschen verstehen 'broken English'; Computer verstehen kein 'broken C++' oder 'broken Julia'. Die Syntax muss beherrscht werden.\n",
    "- **„Ökosystem“ der Sprache:**  \n",
    "      Wie führe ich meinen Code aus? Wie funktionieren die Entwicklungsumgebungen? Welche Optionen versteht der Compiler? Wie installiere ich Zusatzbibliotheken? Wie lese ich Fehlermeldungen? Wo kann ich mich informieren? \n",
    "- **die Kunst des Debugging:**   \n",
    "      Programmieranfänger sind oft glücklich, wenn sie alle Syntaxfehler eliminiert haben und das Programm endlich 'durchläuft'. Bei komplexeren Programmen fängt die Arbeit jetzt erst an, denn nun muss getestet und die Fehler im Algorithmus gefunden und behoben werden. \n",
    "- **Gefühl für die Effizienz und Komplexität von Algorithmen**\n",
    "- **Besonderheiten der Computerarithmetik**, insbesondere der Gleitkommazahlen\n",
    "\n",
    "Das erschließt sich nicht alles auf einmal. Haben Sie Geduld mit sich und 'spielen' Sie mit der Sprache. \n",
    "\n",
    "Das Folgende soll eine kleine Anregung dazu sein.\n",
    "\n",
    "## Project Euler\n",
    "\n",
    "Eine hübsche Quelle für Programmieraufgaben mit mathematischem Charakter und  sehr unterschiedlichen Schwierigkeitsgraden ist [Project Euler](https://projecteuler.net/). \n",
    "Die Aufgaben sind  so gestaltet, dass keinerlei Eingaben notwendig und das gesuchte Ergebnis eine einzige Zahl ist.  So kann man sich voll auf das Programmieren des Algorithmus konzentrieren. \n",
    "\n",
    "---------\n",
    "\n",
    "### Beispiel 1\n",
    "\n",
    "::::::{.content-hidden unless-format=\"xxx\"}\n",
    "\n",
    "https://github.com/luckytoilet/projecteuler-solutions/blob/master/Solutions.md\n",
    "https://math.stackexchange.com/questions/3370978/iterating-sum-of-squares-of-decimal-digits-of-an-integer-how-big-can-it-grow\n",
    "aufg. 92\n",
    "\n",
    ":::\n",
    "\n",
    "::: {.callout-note icon=false .titlenormal}\n",
    "## Project Euler Problem No 1\n",
    "\n",
    "If we list all the natural numbers below 10 that are multiples of 3 or 5, we get 3, 5, 6 and 9. The sum of these multiples is 23.\n",
    "\n",
    "Find the sum of all the multiples of 3 or 5 below 1000.\n",
    "\n",
    ":::\n",
    "\n",
    "1. Algorithmus: \n",
    "    - Teste alle natürlichen Zahlen <1000 auf Teilbarkeit durch 3 oder durch 5 und\n",
    "    - summiere die teilbaren Zahlen auf.\n",
    "\n",
    "2. Umsetzung:\n",
    "\n",
    "    Wie liefert Julia den Rest der Ganzzahldivision? Solche Funktionen heißen typischerweise `rem()` (für *remainder*) oder `mod()`. [Nachlesen in der Doku](https://docs.julialang.org/en/v1/base/math/#Base.rem) oder ausprobieren von `?rem` und `?mod` in der Julia-REPL zeigt, dass es beides gibt. Der Unterschied liegt in der Behandlung negativer ganzer Zahlen. Für natürliche Zahlen `n,m` liefern `mod(n,m)` und `rem(n,m)` dasselbe und letzteres hat auch noch die Infix-Form `n % m`.       \n",
    "    \n",
    "    Wie testet man eine Reihe von Werten durch und summiert auf? Da gibt es ein Standardmuster: `for`-Schleife und Akkumulatorvariable:  \n",
    "\n",
    ":::{.callout-caution icon=\"false\" collapse=\"true\" .titlenormal}\n",
    "\n",
    "## Eine Lösungsvariante:\n"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": null,
   "id": "b5ec6b90",
   "metadata": {},
   "outputs": [],
   "source": [
    "s = 0                               # Akkumulatorvariable initialisieren\n",
    "for i in 1:999                      # Schleife   \n",
    "    if i % 3 == 0 || i % 5 == 0     # Test\n",
    "        s += i                      # Zu Akkumulator addieren \n",
    "    end                             # Ende Test\n",
    "end                                 # Ende Schleife\n",
    "println(\" Die Antwort ist: $s\")                          # Ausgabe des Ergebnisses "
   ]
  },
  {
   "cell_type": "markdown",
   "id": "e4de7d69",
   "metadata": {},
   "source": [
    ":::\n",
    "\n",
    "Natürlich geht das auch etwas kürzer:\n",
    "\n",
    ":::{.callout-caution icon=\"false\" collapse=\"true\" .titlenormal}\n",
    "\n",
    "## Noch eine Lösungsvariante:\n"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": null,
   "id": "772bbe68",
   "metadata": {},
   "outputs": [],
   "source": [
    "sum([i for i in 1:999 if i%3==0||i%5==0])"
   ]
  },
  {
   "cell_type": "markdown",
   "id": "b9b95d73",
   "metadata": {},
   "source": [
    ":::\n",
    "\n",
    "\n",
    "-----------\n",
    "\n",
    "### Beispiel 2\n",
    "\n",
    "\n",
    "::: {.callout-note icon=false .titlenormal}\n",
    "## Project Euler Problem No 92\n",
    "A number chain is created by continuously adding the square of the digits in a number to form a new number until it has been seen before.\n",
    "\n",
    "For example,\n",
    "\n",
    "| 44 → 32 → 13 → 10 → **1** → **1**\n",
    "| 85 → **89** → 145 → 42 → 20 → 4 → 16 → 37 → 58 → **89**\n",
    "\n",
    "Therefore any chain that arrives at 1 or 89 will become stuck in an endless loop. What is most amazing is that EVERY starting number will eventually arrive at 1 or 89.\n",
    "\n",
    "How many starting numbers below ten million will arrive at 89?\n",
    ":::\n",
    "\n",
    "Programme kann man [*top-down* und *bottom-up*](https://de.wikipedia.org/wiki/Top-Down-_und_Bottom-Up-Design) entwickeln.\n",
    "*Top-down* würde hier wohl bedeuten: „Wir fangen mit einer Schleife  `for i = 1:9999999` an.“ Der andere Weg führt über einzeln testbare Komponenten und ist oft zielführender. (Und ab einer gewissen Projektgröße nähert man sich sowieso von  'top' und 'bottom' gleichzeitig dem Ziel.)\n",
    "\n",
    "#####  Funktion Nr. 1\n",
    "Es soll untersucht werden, wie sich die Zahlen unter dem wiederholten Berechnen der 'Quadratquersumme' (Summe der Quadrate der Ziffern) verhalten. Also sollte man eine Funktion schreiben und testen, die diese 'Quadratquersumme' berechnet. \n",
    "\n",
    "\n",
    ":::{.callout-caution icon=\"false\" collapse=\"true\" .titlenormal}\n",
    "\n",
    "## `q2sum(n)` berechnet die Summe der Quadrate der Ziffern von n im Dezimalsystem:\n"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": null,
   "id": "c0730a2a",
   "metadata": {},
   "outputs": [],
   "source": [
    "#| output: false\n",
    "function q2sum(n)\n",
    "    s = 0                         # Akkumulator für die Summe\n",
    "    while n > 9                   # solange noch mehrstellig...\n",
    "       q, r = divrem(n, 10)       # berechne Ganzzahlquotient und Rest bei Division durch 10\n",
    "       s += r^2                   # addiere quadrierte Ziffer zum Akkumulator\n",
    "       n = q                      # mache weiter mit der durch 10 geteilten Zahl\n",
    "    end\n",
    "    s += n^2                      # addiere das Quadrat der letzten Ziffer\n",
    "    return s\n",
    "end"
   ]
  },
  {
   "cell_type": "markdown",
   "id": "1caa208b",
   "metadata": {},
   "source": [
    ":::\n",
    "... und das testen wir jetzt natürlich:\n"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": null,
   "id": "72341556",
   "metadata": {},
   "outputs": [],
   "source": [
    "for i in [1, 7, 33, 111, 321, 1000, 73201]\n",
    "   j = q2sum(i)\n",
    "   println(\"Quadratquersumme von $i = $j\")\n",
    "end"
   ]
  },
  {
   "cell_type": "markdown",
   "id": "5eeb2626",
   "metadata": {},
   "source": [
    "Im Sinne der Aufgabe wenden wir die  Funktion wiederholt an:\n"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": null,
   "id": "da47c136",
   "metadata": {},
   "outputs": [],
   "source": [
    "n = 129956799\n",
    "for i in 1:14\n",
    "    n = q2sum(n)\n",
    "    println(n)\n",
    "end"
   ]
  },
  {
   "cell_type": "markdown",
   "id": "e67b1670",
   "metadata": {},
   "source": [
    "... und haben hier einen der '89er Zyklen' getroffen.\n",
    "\n",
    "\n",
    "#### Funktion Nr. 2\n",
    "\n",
    "Wir müssen testen, ob die wiederholte Anwendung der Funktion `q2sum()` schließlich zu **1** führt oder in diesem **89er**-Zyklus endet.\n",
    "\n",
    ":::{.callout-caution icon=\"false\" collapse=\"true\" .titlenormal}\n",
    "\n",
    "## `q2test(n)` ermittelt, ob wiederholte Quadratquersummenbildung in den 89er-Zyklus führt:\n"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": null,
   "id": "3868d34e",
   "metadata": {},
   "outputs": [],
   "source": [
    "#| output: false\n",
    "function q2test(n)\n",
    "    while n !=1 && n != 89       # solange wir nicht bei 1 oder 89 angekommen sind....\n",
    "        n = q2sum(n)             # wiederholen \n",
    "    end\n",
    "    if n==1 return false end     # keine 89er-Zahl\n",
    "    return true                  # 89er-Zahl gefunden\n",
    "end"
   ]
  },
  {
   "cell_type": "markdown",
   "id": "10ce44d1",
   "metadata": {},
   "source": [
    ":::\n",
    "\n",
    "... und damit können wir die Aufgabe lösen:\n"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": null,
   "id": "54521e6a",
   "metadata": {},
   "outputs": [],
   "source": [
    "c = 0                        # mal wieder ein Akkumulator\n",
    "for i = 1 : 10_000_000 - 1   # so kann man in Julia Tausenderblöcke zur besseren Lesbarkeit abtrennen\n",
    "    if q2test(i)             # q2test() gibt einen Boolean zurück, kein weiterer Test nötig \n",
    "        c += 1               #    'if x == true' ist redundant, 'if x' reicht völlig \n",
    "    end     \n",
    "end\n",
    "println(\"$c numbers below ten million arrive at 89.\")"
   ]
  },
  {
   "cell_type": "markdown",
   "id": "4a545b8c",
   "metadata": {},
   "source": [
    "Zahlen, bei denen die iterierte Quadratquersummenbildung bei 1 endet, heißen übrigens [fröhliche Zahlen](https://de.wikipedia.org/wiki/Fr%C3%B6hliche_Zahl)  und wir haben gerade die Anzahl der traurigen Zahlen kleiner als 10.000.000 berechnet.\n",
    "\n",
    "Hier nochmal das vollständige Programm:\n",
    "\n",
    ":::{.callout-caution icon=\"false\" collapse=\"true\" .titlenormal}\n",
    "## unsere Lösung von Project Euler No 92:\n"
   ]
  },
  {
   "cell_type": "code",
   "execution_count": null,
   "id": "a7253bc1",
   "metadata": {},
   "outputs": [],
   "source": [
    "function q2sum(n)\n",
    "    s = 0                      \n",
    "    while n > 9                 \n",
    "       q, r = divrem(n, 10)\n",
    "       s += r^2                 \n",
    "       n = q                    \n",
    "    end\n",
    "    s += n^2                    \n",
    "    return s\n",
    "end\n",
    "\n",
    "function q2test(n)\n",
    "    while n !=1 && n != 89      \n",
    "        n = q2sum(n)           \n",
    "    end\n",
    "    if n==1 return false end   \n",
    "    return true                 \n",
    "end\n",
    "\n",
    "c = 0\n",
    "for i = 1 : 10_000_000 - 1   \n",
    "    if q2test(i)\n",
    "        c += 1\n",
    "    end     \n",
    "end\n",
    "println(\"$c numbers below ten million arrive at 89.\")"
   ]
  },
  {
   "cell_type": "markdown",
   "id": "772bec11",
   "metadata": {},
   "source": [
    ":::"
   ]
  }
 ],
 "metadata": {
  "kernelspec": {
   "display_name": "Julia 1.8.5",
   "language": "julia",
   "name": "julia-1.8"
  }
 },
 "nbformat": 4,
 "nbformat_minor": 5
}
